ເນື້ອໃນ

# ຟັງຊັນ CreateUnoService

ສ້າງອິນສະແຕນຊ໌ຂອງບໍລິການ Uno ດ້ວຍ ProcessServiceManager.

### ໄວຍາກອນ:

         CreateUnoService(serviceName As String) As Object

### ປະເພດຄ່າທີ່ສົ່ງກັບ:

Object

### ພາຣາມິເຕີ:

ຊື່ | ປະເພດ | ຄຳອະທິບາຍ
--- | --- | ---
serviceName | String | ຊື່ບໍລິການ. ສຳລັບລາຍຊື່ບໍລິການທີ່ມີໃຫ້, ໃຫ້ເຂົ້າເບິ່ງໜ້າອ້າງອີງ com::sun::star Module.

### ຕົວຢ່າງ:

ຕົວຢ່າງລຸ່ມນີ້ສ້າງຟັງຊັນ FileExists ທີ່ໃຊ້ບໍລິການ com.sun.star.ucb.SimpleFileAccess ເພື່ອທົດສອບວ່າເສັ້ນທາງທີ່ລະບຸເປັນໄຟລ໌ທີ່ມີຢູ່ແລ້ວຫຼືບໍ່.

        Function FileExists(sPath as String) As Boolean
            Dim svcSFA As Object
            Set svcSFA = CreateUnoService("com.sun.star.ucb.SimpleFileAccess")
            Dim bExists As Boolean : bExists = svcSFA.exists(sPath)
            Dim bIsFolder As Boolean : bIsFolder = svcSFA.IsFolder(sPath)
            FileExists = bExists And Not bIsFolder
        End Function ' FileExists

ບໍລິການ UNO ມີເອກະສານອອນໄລນ໌ທີ່ລະອຽດຢູ່ໃນເວັບໄຊ api.libreoffice.org. ເຂົ້າເບິ່ງໜ້າອ້າງອີງ SimpleFileAccess Service ເພື່ອຮຽນຮູ້ເພີ່ມເຕີມກ່ຽວກັບເມທອດ (methods) ຕ່າງໆ.

### ຕົວຢ່າງ:

ໂຄ້ດຕໍ່ໄປນີ້ໃຊ້ບໍລິການ com.sun.star.ui.dialogs.FilePicker ເພື່ອສະແດງໄດອະລັອກເປີດໄຟລ໌:

    Sub Main
       fName = FileOpenDialog ("ກະລຸນາເລືອກໄຟລ໌")
       Print "ໄຟລ໌ທີ່ເລືອກ: "+fName
    End Sub

    Function FileOpenDialog(title As String) As String
       res = com.sun.star.ui.dialogs.ExecutableDialogResults
       filepicker = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
       With filepicker
          .Title = title
          .MultiSelectionMode = True
          .appendFilter("Calc docs","*.ods;*.csv;*.123")
          .appendFilter("Writer or Base docs","*.odt;*.odb")
          .appendFilter("All files","*.*")
           If res.OK = .execute() Then
              files = .getSelectedFiles()
              FileOpenDialog=files(0)
           EndIf
       End With
    End Function ' FileOpenDialog

ຫົວຂໍ້ທີ່ກ່ຽວຂ້ອງ

ຟັງຊັນ CreateUnoServiceWithArguments

ອັອບເຈັກ, ຟັງຊັນ ແລະ ບໍລິການຂອງ UNO

ການໃຊ້ຟັງຊັນ Calc ໃນມາກໂຄ