Python : Platform class

ເນື້ອໃນ

# ການລະບຸລະບົບປະຕິບັດການ

ການລະບຸລະບົບປະຕິບັດການສາມາດເຮັດໄດ້ດ້ວຍພາສາ Python ຫຼື Basic.

## ໂດຍການໃຊ້ຄລາສ Python:

            """ the_module """
            import os, platform
            class Platform():
                @property
                def ComputerName(self): return platform.node()
                @property
                def DirSeparator(self): return os.sep
                @property
                def isLinux(self): return (self.OSName=='Linux')
                @property
                def isMacOSX(self): return (self.OSName=='Darwin')
                @property
                def isWindows(self): return (self.OSName=='Windows')
                @property
                def OSName(self): return platform.system()
                @property
                def PathDelimiter(self): return os.pathsep

## ໂດຍການໃຊ້ໂມດູນຄລາສ Basic:

LibreOffice Basic ບໍ່ສາມາດລະບຸ MacOS X ໄດ້ໂດຍກົງ. ແຕ່ສາມາດລະບຸແພລດຟອມໄດ້ໂດຍໃຊ້ API ຂອງ LibreOffice.

            ''' ຊື່ໂມດູນ: Platform '''
            Option Compatible
            Option ClassModule
            Option Explicit

            Public Property Get ComputerName As String
                If isWindows Then ComputerName = Environ("ComputerName")
            End Property ' Platform.ComputerName

            Public Property Get DirSeparator As String
                DirSeparator = GetPathSeparator()
            End Property ' Platform.DirSeparator

            Public Property Get IsLinux As Boolean
                isLinux = ( GetGUIType()=4 ) ' Applies to macOS as well
            End Property ' Platform.isLinux

            Public Property Get IsMacOSX As Boolean
                isMacOSX = ( OSName="MAC" )
            End Property ' Platform.isMacOSX

            Public Property Get IsWindows As Boolean
                isWindows = ( GetGUIType()=1 )
            End Property ' Platform.isWindows

            Public Property Get OSName As String
                ' ສົ່ງຄືນຊື່ແພລດຟອມເປັນ "MAC", "UNIX", "WIN"
                ' ອ້າງອີງມາຈາກຟັງຊັນ "Tools.UCB.ShowHelperDialog"
                With GlobalScope.Basiclibraries
                    If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
                End With
                Dim keyNode As Object ' com.sun.star.configuration.ConfigurationAccess
                keyNode = Tools.Misc.GetRegistryKeyContent("org.openoffice.Office.Common/Help")
                OSName = keyNode.GetByName("System")
            End Property ' Platform.OSName

            Public Property Get PathDelimiter As String
                Select Case OSName
                    Case "MAC", "UNIX" : PathDelimiter = ":"
                    Case "WIN" : PathDelimiter = ";"
                 End Select
            End Property ' Platform.PathDelimiter

ຕົວປ່ຽນສະພາບແວດລ້ອມ ComputerName ມີໃຫ້ໃຊ້ສະເພາະໃນ Windows ເທົ່ານັ້ນ. ການເອີ້ນໃຊ້ແມັກໂຄຣ Python ຈາກ Basic ຊ່ວຍແກ້ໄຂຂໍ້ຈຳກັດຂອງ LibreOffice Basic ໄດ້.

## ຕົວຢ່າງ:

ດ້ວຍ Python

>>> from < the_module > import Platform

>>> print(Platform().isMacOSX) # ຄຸນສົມບັດອອບເຈັກ

True

>>> input(Platform().OSName) # ຄຸນສົມບັດອອບເຈັກ

Darwin

ຈາກເມນູ ເຄື່ອງມື – ແມັກໂຄຣ - ຣັນແມັກໂຄຣ....

            from < the_module > import Platform
            import screen_io as ui
            p = Platform()
            ui.MsgBox(''.join(['isMacOS: ',str(p.isMacOSX)]),0,p.OSName)

ດ້ວຍ LibreOffice Basic

            Sub Platform_example()
                Dim p As New Platform ' ອິນສະແຕນຊ໌ຂອງຄລາສ Platform
                MsgBox p.isLinux ' ຄຸນສົມບັດອອບເຈັກ
                Print p.isWindows, p.OSName ' ຄຸນສົມບັດອອບເຈັກ
            End Sub ' Platform_example

• ບໍລິການ ScriptForge.Platform ໃຫ້ຂໍ້ມູນຄຸນສົມບັດຕ່າງໆກ່ຽວກັບສະພາບແວດລ້ອມ ແລະ ບໍລິບົດຂອງການເຮັດວຽກໃນປັດຈຸບັນ, ລວມທັງການກວດຫາແພລັດຟອມ.
• ການລະບຸຊື່ລະບົບປະຕິບັດການຢ່າງລະອຽດ ສາມາດໃຊ້ໄດ້ຈາກສູດ Calc INFO("system").

ຫົວຂໍ້ທີ່ກ່ຽວຂ້ອງ

ການນຳເຂົ້າ/ສົ່ງອອກ ຫນ້າຈໍ

ຟັງຊັນ GetPathSeparator

ການຮຽກໃຊ້ສະຄຣິບ Python ຈາກ Basic

ຕົວຢ່າງການຂຽນໂປຣແກຣມ Python

ການຊ່ວຍເຫຼືອສະຄຣິບ Python ຂອງ LibreOffice