ເນື້ອໃນ

# ຄຳສັ່ງ MkDir

ສ້າງໄດເຣັກທໍຣີໃໝ່ໃນສື່ເກັບຂໍ້ມູນ.

### ໄວຍາກອນ:

    MkDir path

### ພາຣາມິເຕີ:

path: ນິພົດສະຕຣິງໃດໜຶ່ງທີ່ລະບຸຊື່ ແລະ ເສັ້ນທາງຂອງໄດເຣັກທໍຣີທີ່ຈະສ້າງ. ທ່ານຍັງສາມາດໃຊ້ ຮູບແບບ URL ໄດ້.

ຖ້າບໍ່ໄດ້ກຳນົດເສັ້ນທາງ, ໄດເຣັກທໍຣີຈະຖືກສ້າງຂຶ້ນໃນໄດເຣັກທໍຣີປັດຈຸບັນ.

### ລະຫັດຂໍ້ຜິດພາດ:

5 ການເອີ້ນໃຊ້ໂປຣຊີເຈີບໍ່ຖືກຕ້ອງ

76 ບໍ່ພົບເສັ້ນທາງ (Path)

### ຕົວຢ່າງ:

    Sub ExampleFileIO
    ' ຕົວຢ່າງສຳລັບຟັງຊັນການຈັດການໄຟລ໌
    Const sFile1 As String = "file://c|/autoexec.bat"
    Const sDir1 As String = "file://c|/Temp"
    Const sSubDir1 As String ="Test"
    Const sFile2 As String = "Copied.tmp"
    Const sFile3 As String = "Renamed.tmp"
    Dim sFile As String
        sFile = sDir1 + "/" + sSubDir1
        ChDir( sDir1 )
        If Dir(sSubDir1,16)="" Then ' ໄດເຣັກທໍຣີມີຢູ່ແລ້ວຫຼືບໍ່?
            MkDir sSubDir1
            MsgBox sFile,0,"ສ້າງໄດເຣັກທໍຣີ"
        End If
        sFile = sFile + "/" + sFile2
        FileCopy sFile1 , sFile
        MsgBox fSysURL(CurDir()),0,"ໄດເຣັກທໍຣີປັດຈຸບັນ"
        MsgBox sFile & Chr(13) & FileDateTime( sFile ),0,"ເວລາສ້າງ"
        MsgBox sFile & Chr(13)& FileLen( sFile ),0,"ຄວາມຍາວໄຟລ໌"
        MsgBox sFile & Chr(13)& GetAttr( sFile ),0,"ຄຸນລັກສະນະໄຟລ໌"
        Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
        ' ປ່ຽນຊື່ໃນໄດເຣັກທໍຣີດຽວກັນ
        sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
        SetAttr( sFile, 0 ) 'ລຶບຄຸນລັກສະນະທັງໝົດ
        MsgBox sFile & Chr(13) & GetAttr( sFile ),0,"ຄຸນລັກສະນະໄຟລ໌ໃໝ່"
        Kill sFile
        RmDir sDir1 + "/" + sSubDir1
    End Sub

    ' ແປງເສັ້ນທາງລະບົບເປັນ URL
    Function fSysURL( fSysFp As String ) As String
    Dim iPos As String
        iPos = 1
        iPos = Instr(iPos,fSysFp, getPathSeparator())
        Do While iPos > 0
            Mid( fSysFp, iPos , 1,"/")
            iPos = Instr(iPos+1,fSysFp, getPathSeparator())
        Loop
        ' ເຄື່ອງໝາຍຈ້ຳສອງເມັດ (colon) ຂອງ DOS
        iPos = Instr(1,fSysFp,":")
        If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
        fSysURL = "file://" & fSysFp
    End Function